" plugins
" curl -fLo ~/.config/nvim/autoload/plug.vim --create-dirs https://raw.githubusercontent.com/junegunn/vim-plug/master/plug.vim
call plug#begin("~/.config/nvim/plugged")
  " Plugin Senohlsearchction
Plug 'ryanoasis/vim-devicons'
Plug 'morhetz/gruvbox'
Plug 'neoclide/coc.nvim', {'branch': 'release'}
Plug 'junegunn/fzf.vim'
Plug 'junegunn/fzf'
Plug 'psliwka/vim-smoothie'
Plug 'majutsushi/tagbar'
Plug 'sheerun/vim-polyglot'
Plug 'puremourning/vimspector'
Plug 'sagi-z/vimspectorpy', { 'do': { -> vimspectorpy#update() } }
Plug 'szw/vim-maximizer'
Plug 'tpope/vim-surround'
Plug 'fisadev/vim-isort'
" Distraction free writing by removing UI elements and centering everything.
Plug 'iamcco/markdown-preview.nvim', { 'do': { -> mkdp#util#install() }, 'for': ['markdown', 'vim-plug']}
Plug 'chrisbra/vim-commentary'
Plug 'robertbasic/vim-hugo-helper'
Plug 'juev/vim-hugo'
call plug#end()

nnoremap <F2> :set invpaste paste?<CR>
set number
set relativenumber
set cursorline
set scroll=10
set scrolloff=10
set pastetoggle=<F2>
set showmode
set hlsearch
set statusline=\ %f%m%r\ %y\ %=\ %c\ [%l/%L]\ %p\%%\ %P\
hi CursorLine ctermbg=237

colorscheme gruvbox
" make sure to install bat, riggrep

autocmd BufEnter *.json.tpl :setlocal filetype=json
command W :execute ':silent w !sudo tee % > /dev/null' | :edit!
command! -bang -nargs=* Rg call fzf#vim#grep('rg --column --line-number --no-heading --color=always --smart-case '.shellescape(<q-args>), 1, fzf#vim#with_preview(), <bang>0)

let g:fzf_action = { 'enter': 'tabedit' }
let g:fzf_layout = { 'down': '~40%' }
nnoremap <silent> <C-f> :Files<CR>
nnoremap <silent> <C-p> :Files<CR>

map <C-K> :bprev <CR>
map <C-J> :bnex <CR>

" quick .vimrc access with ,v
let $NEOVIM = "~/.config/nvim/init.vim"
let mapleader = ","
nmap <leader>v :tabedit $NEOVIM<CR>
nmap <leader>a :ls<CR>
nmap <leader>w :Windows<CR>
map <C-r> :source $NEOVIM<CR>
nmap <C-f> :Files<CR>
nmap <leader>ss :nohlsearch<CR>
nmap <leader>tt :tabonly<CR>
"nmap <leader>x :!xclip -selection c %<CR><CR>
nmap <leader>x :!pbcopy < %<CR><CR>
vnoremap <leader>x :w !pbcopy<CR><CR>

"nmap gx yiW:!xdg-open <c-r>" & <CR><CR>

"Example:
"gCtrl aa - increment visually selected block plus +1 next number plus +2, ...
"Ctrl aa  - increments everything +1
xnoremap <expr> <c-a> "\<esc>'<V'>".v:count1."\<c-a>"

let g:vimspector_enable_mappings = 'HUMAN'
source $HOME/.config/nvim/plug-config/coc.vim

" Vimspector
" pip3 install --trusted-host pypi.python.org --trusted-host files.pythonhosted.org --trusted-host pypi.org  pynvim jedi

iab bashh
\<CR>```
\<CR>
\<CR>```<ESC>ki

iab yamll
\<CR>```yaml
\<CR>
\<CR>```<ESC>ki

iab eoff
\<CR>cat <<'EOF' > filename
\<CR>
\<CR>EOF<ESC>ki

iabbrev iii 

" Setup Hugo post
let g:hugo_path = "~/Documents/hugo/devopsinuse/hugo"
let g:hugo_post_dirs = "/content/english/blog/"
let g:hugo_post_suffix = "md"
let g:hugo_title_pattern = "[ '\"]"

I am using a custom hugo theme called bigspring (paid one) and files/directory structure is a custom one. When it comes to juev/vim-hugo plugin I had to manually reconfigure it it following fashion. File: cat ~/.config/nvim/plugged/vim-hugo/plugin/hugo.vim

" hugo.vim
" Author:  Denis Evsyukov <denis@evsyukov.org>
" URL:     https://github.com/juev/vim-hugo
" Version: 0.1.0
" License: Same as Vim itself (see :help license)

if exists('g:loaded_hugo') || &cp || v:version < 700
  finish
endif
let g:loaded_hugo = 1

" Configuration {{{

if ! exists('g:hugo_path')
  let g:hugo_path = "~/blog"
endif

if ! exists('g:hugo_post_dirs')
  let g:hugo_post_dirs = "/content/posts/"
endif

if !exists('g:hugo_post_suffix')
  let g:hugo_post_suffix = "markdown"
endif

if !exists('g:hugo_title_pattern')
  let g:hugo_title_pattern = "[ '\"]"
endif

" }}}

" Utility functions {{{

function! s:esctitle(str)
  let str = a:str
  let str = tolower(str)
  let str = substitute(str, g:hugo_title_pattern, '-', 'g')
  let str = substitute(str, '\(--\)\+', '-', 'g')
  let str = substitute(str, '\(^-\|-$\)', '', 'g')
  return str
endfunction

function! s:error(str)
  echohl ErrorMsg
  echomsg a:str
  echohl None
  let v:errmsg = a:str
endfunction

" }}}

" Post functions {{{

function! HugoPost(title)
  let created = strftime("%FT%T%z") " 2019-10-24T08:56:12+03:00
  let title = a:title
  if title == ''
    let title = input("Post title: ")
  endif
  if title != ''
    "let file_name = strftime("%Y-%m-%d-") . s:esctitle(title) . "." . g:hugo_post_suffix
    let file_name = s:esctitle(title) . "." . g:hugo_post_suffix
    echo "Making that post " . file_name
    exe "e " . g:hugo_path . g:hugo_post_dirs . file_name

    let template = ["---", "title: \"" . title . "\"", "date: " . created, "lastmod: " . created, "draft: false", "description: \"" . title . "\"", "image: \"images/blog/linux-1.jpg\"", "author: \"Jan Toth\"", "tags: ", "  - "]
    call extend(template,["---", ""])

    let err = append(0, template)
  else
    call s:error("You must specify a title")
  endif
endfunction
command! -nargs=? HugoPost :call HugoPost(<q-args>)



" }}}

" vim:ft=vim:fdm=marker:ts=2:sw=2:sts=2:et

Coc settings file cat ~/.config/nvim/coc-settings.json

{
  "coc.preferences.formatOnSaveFiletypes": ["css", "markdown", "javascript", "graphql", "html", "yaml",  "json", "python"],

  // python config
  "coc.preferences.jumpCommand": "tabe",
  "python.linting.enabled": true,
  "python.linting.pylintEnabled": true,
  "python.formatting.provider": "autopep8",
  "python.pythonPath": "~/.config/nvim/coc-python-path.sh",
  "snippets.ultisnips.directories":
  [
    "UltiSnips",
    "~/.config/nvim/utils/snips"
  ]

}

cat ~/.config/nvim/coc-python-path.sh

#!/bin/bash
python3 "$@"

cat ~/.config/nvim/plug-config/coc.vim

" Set internal encoding of vim, not needed on neovim, since coc.nvim using some
" unicode characters in the file autoload/float.vim
set encoding=utf-8

" TextEdit might fail if hidden is not set.
set hidden

" Some servers have issues with backup files, see #649.
set nobackup
set nowritebackup

" Give more space for displaying messages.
set cmdheight=2

" Having longer updatetime (default is 4000 ms = 4 s) leads to noticeable
" delays and poor user experience.
set updatetime=300

" Don't pass messages to |ins-completion-menu|.
set shortmess+=c

" Always show the signcolumn, otherwise it would shift the text each time
" diagnostics appear/become resolved.
if has("nvim-0.5.0") || has("patch-8.1.1564")
  " Recently vim can merge signcolumn and number column into one
  set signcolumn=number
else
  set signcolumn=yes
endif

" Use tab for trigger completion with characters ahead and navigate.
" NOTE: Use command ':verbose imap <tab>' to make sure tab is not mapped by
" other plugin before putting this into your config.
inoremap <silent><expr> <TAB>
      \ pumvisible() ? "\<C-n>" :
      \ <SID>check_back_space() ? "\<TAB>" :
      \ coc#refresh()
inoremap <expr><S-TAB> pumvisible() ? "\<C-p>" : "\<C-h>"

function! s:check_back_space() abort
  let col = col('.') - 1
  return !col || getline('.')[col - 1]  =~# '\s'
endfunction

" Use <c-space> to trigger completion.
if has('nvim')
  inoremap <silent><expr> <c-space> coc#refresh()
else
  inoremap <silent><expr> <c-@> coc#refresh()
endif

" Make <CR> auto-select the first completion item and notify coc.nvim to
" format on enter, <cr> could be remapped by other vim plugin
inoremap <silent><expr> <cr> pumvisible() ? coc#_select_confirm()
                              \: "\<C-g>u\<CR>\<c-r>=coc#on_enter()\<CR>"

" Use `[g` and `]g` to navigate diagnostics
" Use `:CocDiagnostics` to get all diagnostics of current buffer in location list.
nmap <silent> [g <Plug>(coc-diagnostic-prev)
nmap <silent> ]g <Plug>(coc-diagnostic-next)

" GoTo code navigation.
nmap <silent> gd <Plug>(coc-definition)
nmap <silent> gy <Plug>(coc-type-definition)
nmap <silent> gi <Plug>(coc-implementation)
nmap <silent> gr <Plug>(coc-references)

" Use K to show documentation in preview window.
nnoremap <silent> K :call <SID>show_documentation()<CR>

function! s:show_documentation()
  if (index(['vim','help'], &filetype) >= 0)
    execute 'h '.expand('<cword>')
  elseif (coc#rpc#ready())
    call CocActionAsync('doHover')
  else
    execute '!' . &keywordprg . " " . expand('<cword>')
  endif
endfunction

" Highlight the symbol and its references when holding the cursor.
autocmd CursorHold * silent call CocActionAsync('highlight')

" Symbol renaming.
nmap <leader>rn <Plug>(coc-rename)

" Formatting selected code.
xmap <leader>f  <Plug>(coc-format-selected)
nmap <leader>f  <Plug>(coc-format-selected)

augroup mygroup
  autocmd!
  " Setup formatexpr specified filetype(s).
  autocmd FileType typescript,json setl formatexpr=CocAction('formatSelected')
  " Update signature help on jump placeholder.
  autocmd User CocJumpPlaceholder call CocActionAsync('showSignatureHelp')
augroup end

" Applying codeAction to the selected region.
" Example: `<leader>aap` for current paragraph
xmap <leader>a  <Plug>(coc-codeaction-selected)
nmap <leader>a  <Plug>(coc-codeaction-selected)

" Remap keys for applying codeAction to the current buffer.
nmap <leader>ac  <Plug>(coc-codeaction)
" Apply AutoFix to problem on the current line.
nmap <leader>qf  <Plug>(coc-fix-current)

" Map function and class text objects
" NOTE: Requires 'textDocument.documentSymbol' support from the language server.
xmap if <Plug>(coc-funcobj-i)
omap if <Plug>(coc-funcobj-i)
xmap af <Plug>(coc-funcobj-a)
omap af <Plug>(coc-funcobj-a)
xmap ic <Plug>(coc-classobj-i)
omap ic <Plug>(coc-classobj-i)
xmap ac <Plug>(coc-classobj-a)
omap ac <Plug>(coc-classobj-a)

" Remap <C-f> and <C-b> for scroll float windows/popups.
if has('nvim-0.4.0') || has('patch-8.2.0750')
  nnoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? coc#float#scroll(1) : "\<C-f>"
  nnoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? coc#float#scroll(0) : "\<C-b>"
  inoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? "\<c-r>=coc#float#scroll(1)\<cr>" : "\<Right>"
  inoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? "\<c-r>=coc#float#scroll(0)\<cr>" : "\<Left>"
  vnoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? coc#float#scroll(1) : "\<C-f>"
  vnoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? coc#float#scroll(0) : "\<C-b>"
endif

" Use CTRL-S for selections ranges.
" Requires 'textDocument/selectionRange' support of language server.
nmap <silent> <C-s> <Plug>(coc-range-select)
xmap <silent> <C-s> <Plug>(coc-range-select)

" Add `:Format` command to format current buffer.
command! -nargs=0 Format :call CocAction('format')

" Add `:Fold` command to fold current buffer.
command! -nargs=? Fold :call     CocAction('fold', <f-args>)

" Add `:OR` command for organize imports of the current buffer.
command! -nargs=0 OR   :call     CocAction('runCommand', 'editor.action.organizeImport')

" Add (Neo)Vim's native statusline support.
" NOTE: Please see `:h coc-status` for integrations with external plugins that
" provide custom statusline: lightline.vim, vim-airline.
set statusline^=%{coc#status()}%{get(b:,'coc_current_function','')}

" Mappings for CoCList
" Show all diagnostics.
nnoremap <silent><nowait> <space>a  :<C-u>CocList diagnostics<cr>
" Manage extensions.
nnoremap <silent><nowait> <space>e  :<C-u>CocList extensions<cr>
" Show commands.
nnoremap <silent><nowait> <space>c  :<C-u>CocList commands<cr>
" Find symbol of current document.
nnoremap <silent><nowait> <space>o  :<C-u>CocList outline<cr>
" Search workspace symbols.
nnoremap <silent><nowait> <space>s  :<C-u>CocList -I symbols<cr>
" Do default action for next item.
nnoremap <silent><nowait> <space>j  :<C-u>CocNext<CR>
" Do default action for previous item.
nnoremap <silent><nowait> <space>k  :<C-u>CocPrev<CR>
" Resume latest coc list.
nnoremap <silent><nowait> <space>p  :<C-u>CocListResume<CR>